@ECHO OFF
SETLOCAL
SETLOCAL ENABLEDELAYEDEXPANSION

SET PATH=%PATH%;C:\Program Files\Veritas\NetBackup\bin\admincmd

ECHO DATE	TIME	SERVER	CLIENT	SEVERITY	JOBID	TYPE	DESC

REM FOR /F "delims=: tokens=1,*" %%i IN ('cmd.exe /C "bperror.exe -all -L -hoursago 24 | findstr /N /R .*"') DO (
REM 	IF "%%j"=="" (
FOR /F "tokens=*" %%i IN ('cmd.exe /C "bperror.exe -all -L -hoursago 24 | findstr /N /R .*"') DO (
	SET _line=%%i
	SET _line=!_line:*:=!
	IF "!_line!"=="" (
		IF NOT "!_date!"=="" ECHO !_date!	!_time!	!_server!	!_client!	!_severity!	!_jobid!	!_type!	!_desc!
		SET _date=
		SET _time=
		SET _server=
		SET _client=
		SET _severity=
		SET _jobid=
		SET _type=
		SET _desc=
	) ELSE (
		IF NOT "!_line:~0,1!"==" " (
			SET _num=1
			FOR /F "tokens=1,2,3,4,5,6,*" %%i IN ("!_line!") DO (
				SET _date=%%i
				SET _date=!_date:~2,2!/!_date:~0,2!/!_date:~4!
				SET _time=%%j
				SET _server=%%l
				SET _server=!_server:~2!
				SET _client=%%m
				SET _client=!_client:~2!
				IF "!_client!"=="?" SET _client=
				SET _jobid=%%n
				SET _jobid=!_jobid:~2!
			)
		) ELSE IF !_num!==1 (
			SET /A _num=!_num! + 1
			FOR /F "tokens=1,2,3,*" %%i IN ("!_line!") DO (
				SET _severity=%%i
				FOR /F "delims=() tokens=1,*" %%i IN ("!_severity!") DO (
					SET _severity=%%i
				)
				SET _type=%%k
				FOR /F "delims=() tokens=1,*" %%i IN ("!_type!") DO (
					SET _type=%%i
				)
			)
		) ELSE (
			IF "!_desc!"=="" (
				SET _desc=!_line:~2!
			) ELSE (
				SET _desc=!_desc! !_line:~2!
			)
		)
	)
)
IF NOT "!_date!"=="" ECHO !_date!	!_time!	!_server!	!_client!	!_severity!	!_jobid!	!_type!	!_desc!