Netbackup Backup Replication

To see the backup and replication and import process for a file which won't (or shouldn't - but parts still might) deduplicate... then...

...here's a simple script to create a file containing random data:

Option Explicit
Dim go_fso
Dim gs_script_spec, gs_script_path, gs_script_name
Dim gs_arg_file, gs_arg_mb, gl_arg_mb
  Call s_init()
' Call s_method1()
  Call s_method2()
WScript.Quit

Sub s_init()
  Set go_fso = CreateObject( "Scripting.FileSystemObject" )
  gs_script_spec = WScript.ScriptFullName
  gs_script_path = go_fso.GetParentFolderName( gs_script_spec )
  gs_script_name = go_fso.GetBaseName(         gs_script_spec )
  gs_arg_file = gs_script_name & ".bin"
  gl_arg_mb   = 1
  Select Case WScript.Arguments.Count
  Case 0
  Case 1
    gs_arg_file = WScript.Arguments.Item( 0 )
  Case 2
    gs_arg_file = WScript.Arguments.Item( 0 )
    gs_arg_mb   = WScript.Arguments.Item( 1 )
    If Not IsNumeric( gs_arg_mb ) Then Call s_abort( "P2 must be numeric size for MB" )
    gl_arg_mb = CLng( gs_arg_mb )
    If gl_arg_mb < 1 Then Call s_abort( "P2 must be 1 or more" )
  Case Else
    Call s_abort( "too many arguments, only 2 allowed" )
  End Select
  Randomize
End Sub

Sub s_abort( ps_text )
  WScript.Echo ps_text
  WScript.Quit( 1 )
End Sub

Sub s_method1()
  Dim lo_chan, ls_out, ls_add, ll_i, ll_j, ll_MB
  Set lo_chan = go_fso.CreateTextFile( gs_arg_file, True )
  For ll_MB = 1 To gl_arg_mb
    WScript.StdOut.Write vbCr & ll_MB & " "
    ls_out = ""
    For ll_i = 1 To 1023
      Randomize
      ls_add = ""
      For ll_j = 1 To 1024
        ls_add = ls_add & Chr( Int( Rnd * 256 ) )
      Next
      ls_out = ls_out & ls_add
    Next
    ls_add = ""
    For ll_j = 1 To 1022
      ls_add = ls_add & Chr( Int( Rnd * 256 ) )
    Next
    ls_out = ls_out & ls_add
    lo_chan.WriteLine ls_out
  Next
  lo_chan.Close
End Sub

Sub s_method2()
  Dim lo_stream, lx_data(511), ll_i, ll_j, ls_buffer, ll_MB
  Set lo_stream = CreateObject( "ADODB.Stream" )
  lo_stream.Type = 1
  lo_stream.Open
  For ll_MB = 1 To gl_arg_mb
    WScript.StdOut.Write vbCr & ll_MB & " "
    For ll_j = 1 To 1024
      Randomize
      For ll_i = LBound( lx_data ) To UBound( lx_data )
        lx_data( ll_i ) = ChrW( ( Int( Rnd * 256 ) * 256 ) + Int( Rnd * 256 ) )
      next
      ls_buffer = Join( lx_data, "" )

      With CreateObject( "ADODB.Stream" )
        .type = 2
        .Open
        .WriteText ls_buffer
        .Position = 2
        .CopyTo lo_stream
      End With
    Next
  Next
  lo_stream.SaveToFile gs_arg_file, 2
  lo_stream.Close
End Sub

.

Save it as:   C:\temp\make-random.vbs

.

Run it with:

C:\temp> cscript make-random.vbs a.bin 100

...to create a file name "a.bin" containing 100 MB of random bits/bytes.

Thanks for taking a look.

I thought that this was the first time that the data was seen so I was expecting to see >20GB to have been replicated.  If the backups and replications expired, would this cause the full 20GB to be replicated again?