Here is the script; dbbackup_notify.cmd and it exists in /netbackup/bin of master server
@REM
@REM $Header: dbbackup_notify.cmd,v 1.2 2002/11/20 02:10:42 $
@REM
@REM bcpyrght
@REM ***************************************************************************
@REM * $VRTScprght: Copyright 1993 - 2006 Symantec Corporation, All Rights Reserved $ *
@REM ***************************************************************************
@REM ecpyrght
@REM
@REM dbbackup_notify.cmd
@REM
@REM this script is called by NetBackup after all NetBackup databases have
@REM been backed up and is passed
@REM
@REM this script:
@REM should be able to handle a list of parameter triplets:
@REM media_type path_or_mediaID SUCCESS_or_FAIL
@REM media_type and path_or_mediaID may be UNKNOWN
@REM
@REM - Main program ------------------------------------------------------------
@REM -
@REM - This script only runs on NT 4.0 and succeeding versions of NT. You must
@REM - have command extensions enabled. Check the following registry entry:
@REM -
@REM - HKEY_CURRENT_USER\Software\Microsoft\Command Processor\EnableExtensions
@REM -
@REM - It should be set to 0x1 or you may have problems running this script.
@REM ---------------------------------------------------------------------------
@setlocal ENABLEEXTENSIONS
@set LISTPATHS="%~dp0\goodies\listpaths"
@for /F "delims=|" %%p in ('%LISTPATHS% /s NB_MAIL_SCRIPT') do @set NB_MAIL_SCRIPT="%%p"
@set OUTF="%~dp0\DBBACKUP_CALLED"
@set OKMSG=NetBackup databases backed up on
@set FAILMSG=NetBackup database backup FAILED to
@REM ---------------------------------------------------------------------------
@REM - Get date and time.
@REM ---------------------------------------------------------------------------
@for /F "tokens=1*" %%p in ('date /T') do @set DATE=%%p %%q
@for /F %%p in ('time /T') do @set DATE=%DATE% %%p
@REM ---------------------------------------------------------------------------
@REM - Check for proper parameter use.
@REM ---------------------------------------------------------------------------
@if NOT "%3" == "" goto GoodParams
@echo %DATE% dbbackup_notify requires at least 3 parameters >> %OUTF%
@echo %DATE% dbbackup_notify requires at least 3 parameters
@goto EndMain
:GoodParams
@REM ---------------------------------------------------------------------------
@REM you may want to delete this file
@REM if the file's length becomes excessive
@REM if exist %OUTF% del %OUTF%
@REM ---------------------------------------------------------------------------
:MainLoop
@REM ---------------------------------------------------------------------------
@REM - Check that the first parameter if valid.
@REM ---------------------------------------------------------------------------
@if "%1" == "UNKNOWN" goto FirstParamGood
@if "%1" == "OPTICAL" goto FirstParamGood
@if "%1" == "TAPE" goto FirstParamGood
@if "%1" == "DISK" goto FirstParamGood
@REM ---------------------------------------------------------------------------
@REM - First parameter is bad, abort.
@REM ---------------------------------------------------------------------------
echo %DATE% invalid 1st param: %1 >> %OUTF%
@goto SendNotification
@REM ---------------------------------------------------------------------------
:FirstParamGood
@REM ---------------------------------------------------------------------------
@REM - Check third parameter to see if database backup was successful.
@REM ---------------------------------------------------------------------------
@if NOT "%3" == "SUCCESS" goto TryFailure
@echo %DATE% %OKMSG% %1 %2 >> %OUTF%
@goto EndMainLoop
:TryFailure
@REM ---------------------------------------------------------------------------
@if NOT "%3" == "FAIL" goto ThirdParamBad
@echo %DATE% %FAILMSG% %1 %2 >> %OUTF%
@goto EndMainLoop
:ThirdParamBad
@REM ---------------------------------------------------------------------------
@REM - Third parameter is bad, abort.
@REM ---------------------------------------------------------------------------
@echo %DATE% invalid 3rd param: %3 >> %OUTF%
@goto SendNotification
:EndMainLoop
@shift /1
@shift /1
@shift /1
@if "%1" == "" goto SendNotification
@if NOT "%3" == "" goto MainLoop
@REM ---------------------------------------------------------------------------
@REM - improper. parameters must be in triplets.
@echo %DATE% invalid parameter(s): %* >> %OUTF%
@REM ---------------------------------------------------------------------------
:SendNotification
@REM ---------------------------------------------------------------------------
@REM - might want to mail this info to someone
@REM -
@REM - @call %NB_MAIL_SCRIPT% someone_who_cares "NetBackup db backup" %OUTF%
@REM ---------------------------------------------------------------------------
:EndMain
@endlocal
@REM - End of Main Program -----------------------------------------------------